No part of this work may be reproduced or transmitted in any form or by any means, electronic or mechanical, including photocopying, recording, or by any information storage and retrieval system, without permission in writing from the publisher. However, you are permitted to make copies of this work, printed or otherwise, as long as said copies are for your personal use only.
-------
How many times have your Watch Me scripts failed because the prompts you were looking for weren't there? Watch Me scripts are great, but they work well only when dealing with hosts that don't do fancy things during the log on process. For example, if your host gives you a prompt like this:
login 04:58:22>
Watch Me will happily generate a script similar to this:
Dial Service "'My Host'"
Wait for Text "'8:22>'"
Send Text String "'bla bla bla^M'"
What if that number is the time of day? The next time you log onto the system, your prompt might be:
login 06:19:13>
If you attempt to run your Watch Me generated script, it will fail. What you need to do is write a script that looks for the part of a prompt that will not change. In the case of this host, you'll want to look for the word 'login'. Your script might look something like this:
Dial Service "'My Host'"
Wait for Text "'login'"
Remark "--- wait another second to let"
Remark "--- the rest of the prompt in"
Wait Seconds "1"
Send Text String "'bla bla bla^M'"
This is one step better than the Watch Me script. However, it is not foolproof. What if your host is really picky and may or may not show you a prompt when you log on. You might need to hit the carriage return a couple of times before that elusive prompt even shows up. This script will handle that situation:
Dial Service "'My Host'"
Repeat
When Seconds Have Passed "1"
Send Text String "'^M'"
Or When Text Equals "'login'"
End When
Until Text Equals "'login'"
Remark "--- wait another second to let"
Remark "--- the rest of the prompt in"
Wait Seconds "1"
Send Text String "'bla bla bla^M'"
This script contains a repeat loop that repeatedly checks for two conditions: has a second of time gone by, or have we seen a 'login' on the screen? If a second has gone by, the script sends out a carriage return, hoping to wake up the host. If the 'login' appears on the screen, the script leaves the repeat loop, waits a second for the rest of the prompt to come through, and sends out the login information.
WE'RE ON, ALMOST
OK, now you have successfully logged on, but you get a series of annoying '--more--' messages on your screen, to which you are supposed to respond by hitting the spacebar or carriage return. Problem is, you don't know how many of these you are going to get until you finally get the prompt you are looking for, in this case, the prompt 'happy:-)', which designates your final arrival to a place where you can get some real work done.
Here's a script that handles the problem. It looks for the '--more--' prompt, and if it sees it, send out a space. It does this until it sees the 'happy:-)' prompt.
Repeat
When Text Equals "'--more--'"
Send Text String "' '"
Remark "--- wait another second for good measure"
Wait Seconds "1"
Or When Text Equals "'happy:-)'"
End When
Until Text Equals "'happy:-)'"
You're probably asking yourself, what is this "second for good measure" stuff? Well, when we send out the space, it's going to take a while for the host to echo it back to us. Since MicroPhone scripts go at a blazingly fast speed, we will make another run through the repeat loop, see the '--more--' prompt again (because the host hasn't sent us back the space yet) and promptly (pun intended) send out another space. We'll probably end up doing this several hundred times, flooding the poor host with spaces before it gets a chance to send us back the space we sent it. By placing a Wait Seconds after the Send Text String, we give the host enough time to process the space and echo it back, ensuring us that we won't see the same '--more--' prompt again.
Now, you are saying, why didn't we just use the "When Text In Stream Is" command? Doesn't it prevent this problem? Yes, it does, and here's the same script using When Text In Stream Is:
Repeat
When Text In Stream Is "'--more--'"
Send Text String "' '"
Or When Text Equals "'happy:-)'"
End When
Until Text Equals "'happy:-)'"
The advantage of using When Text Equals and the Wait Seconds commands is that we prevent ourselves from being in a tight loop, allowing text to flow into MicroPhone's terminal window faster. The Wait Seconds command allows as much text to flow into the terminal window as possible in the given number of seconds, without evaluating each character as it comes through.
If we have a tight loop like the last example, MicroPhone has to go through the when loop for each and every character that passes through the serial port, which takes a lot of processing time. By sending out a space character and waiting a second, we allow a second's worth of characters to get through without evaluating them. We aren't interested in evaluating them because we know that a lot of text is going to come through before we see another '--more--' prompt.
So, why can't we use the "When Text In Stream Is" along with a Wait Seconds command? Because we might get a '--more--' prompt before a second has past, which the "When Text In Stream Is" command will not pick up. "When Text In Stream Is" will only process characters as they come through the serial port. Once they are on the screen, even if the cursor is to the very right of the characters, it is too late for "When Text In Stream Is" to work. However, the "When Text Equals" command will pick these characters up.
